We explain some advanced usages.

Insert the name of the directory where the downloaded files are located.

SetDirectory[NotebookDirectory[]];
<<multipleZeta`

The order of summation does matter:

hplSum[(1/((((k+m))^2)(2*m+4*k+1))),{k,1,∞},{m,1,∞},hplN]

Short[hplSum[(1/((((k+m))^2)(2*m+4*k+1))),{m,1,∞},{k,1,∞},hplN],10]

This example shows that internally different paths are taken, and also the final expressions look different because reduction of MZVs with 8th root of unity is not implemented.

One may stop converting to polygamma and polylog by setting the option Simplify->False.

hplSum[(1/((((1+n+ν))^2)(1+m+n+ν)*(m+n+1))),{n,0,∞},{m,0,∞},ν]

hplSum[(1/((((1+n+ν))^2)(1+m+n+ν)*(m+n+1))),{n,0,∞},{m,0,∞},ν,Simplify->False]

Another example for the same purpose:

hplSum[((((-1))^(k+m))/((((k+1))^2)(2*m+1))),{k,2,∞},{m,1,k-1},hplN]

hplSum[((((-1))^(k+m))/((((k+1))^2)(2*m+1))),{k,2,∞},{m,1,k-1},hplN,Simplify->False]

%//hplExpandProjector

%//hplMZVSimplify

In this case, it is not very helpful to stop simplifying...

One may use hplMZVSimplify in the following example to find the value in the limit Λ->∞:

hplSum[(1/(k*(j+Λ))),{k,1,Λ},{j,2,k},Λ,Simplify->False]//hplExpandProjector

%/.Λ->hplN//hplMZVSimplify

In principle the program can compute even if there are parameters in the numerator.

Short[hplSum[((((λ1)^m) ((λ2)^n))/((1+m) (1+n) (1+n+m))),{m,0,∞},{n,0,∞},hplN],10]

This result retains all the surface terms at infinity (hplN).
In the present version, you have to eliminate the surface terms by hand, when you are confident that they vanish.
Let us eliminate the surface terms, by searching those terms which have hplN in the denominator or (λ1 or λ2)^hplN in the numerator.

res=Select[%,FreeQ[Denominator[#],hplN]&&FreeQ[Cancel[#/(#/.{λ->1,λ1->1,λ2->1})/.hplZC[__]->1],hplN]&]

This is lengthy but it is a correct formula.
Namely, the original sum is converted to a combination of nested sums.
Let’s check at special values:

res/.{{λ1->1,λ2->1},{λ1->1,λ2->-1},{λ1->-1,λ2->1},{λ1->-1,λ2->-1}}//hplMZVSimplify

Table[hplSum[((((λ1)^m) ((λ2)^n))/((1+m) (1+n) (1+n+m)))/.{{λ1->1,λ2->1},{λ1->1,λ2->-1},{λ1->-1,λ2->1},{λ1->-1,λ2->-1}}[[i]],{m,0,∞},{n,0,∞},hplN],{i,4}]

%-%%

We can also check by series expansion of first several terms:

Block[{Λ=10},
Sum[((((λ1)^m) ((λ2)^n))/((1+m) (1+n) (1+n+m))),{m,0,Λ},{n,0,Λ}]/.{λ1->x*λ1,λ2->x*λ2}
]+O[x]^8//Normal

Collect[
(res/.hplN->12/.{λ1->x*λ1,λ2->x*λ2}/.hplZC->hplZSum)+
+O[x]^8//Normal,
{x,λ1,λ2},Simplify]

%-%%//Expand